Как динамически помещать значения ячеек в текстовое поле на многостраничной странице в Excel?

Я думаю, это то, что вы пытаетесь?

После того, как вы вставите элемент управления, попробуйте это

'
'~~> Rest of your code
'
MultiPage1.Pages(i).Paste

For Each ctl In Me.MultiPage1.Pages(i).Controls
    If TypeOf ctl Is MSForms.TextBox Then
        '~~> Your code here
        ctl.Text = vID
        Exit For
    End If
Next
'
'~~> Rest of your code
'

Также объявите это как верхнюю часть вашего кода

Dim ctl As Control

ПОСЛЕДУЮЩАЯ ИНФОРМАЦИЯ (из комментариев)

Если у вас есть несколько Controls одного и того же типа, я предпочитаю не копировать и не вставлять их, а воссоздавать их с нуля. Это дает мне больше контроля над этими Controls

Однако, если вы все еще хотите использовать метод «Копировать-вставить», используйте свойство .Tag. См. этот пример

Создайте пользовательскую форму, как показано на снимке ниже.

На странице (0) установите теги для каждого текстового поля.

Давайте используем этот код в пользовательской форме

Option Explicit

Dim ctl As Control

Private Sub CommandButton1_Click()

    Debug.Print "Page (0):-"
    For Each ctl In Me.MultiPage1.Pages(0).Controls
        If TypeOf ctl Is MSForms.TextBox Then
            Debug.Print ctl.Name; "==="; ctl.Tag
        End If
    Next

    Debug.Print "---"
    Debug.Print "Page (1):-"

    MultiPage1.Pages(0).Controls.Copy

    MultiPage1.Pages.Add
    MultiPage1.Pages(1).Paste

    For Each ctl In Me.MultiPage1.Pages(1).Controls
        If TypeOf ctl Is MSForms.TextBox Then
            Debug.Print ctl.Name; "==="; ctl.Tag
        End If
    Next

    Debug.Print "---"
    Debug.Print "Page (2):-"

    MultiPage1.Pages.Add
    MultiPage1.Pages(2).Paste
    For Each ctl In Me.MultiPage1.Pages(2).Controls
        If TypeOf ctl Is MSForms.TextBox Then
            Debug.Print ctl.Name; "==="; ctl.Tag
        End If
    Next
End Sub

Когда вы запустите код, вы увидите этот вывод на экране

Если вы заметили, что .Tag не меняется. Таким образом, мы можем эффективно использовать это, если у нас будет больше элементов управления. См. этот пример

Option Explicit

Dim ctl As Control

Private Sub CommandButton1_Click()
    MultiPage1.Pages(0).Controls.Copy

    MultiPage1.Pages.Add
    MultiPage1.Pages(1).Paste

    For Each ctl In Me.MultiPage1.Pages(1).Controls
        If TypeOf ctl Is MSForms.TextBox Then
            Select Case ctl.Tag
                Case "A"
                    '~~> Your code goes here to put text in this textbox
                    ctl.Text = "AAAA"
                Case "B"
                    '~~> Your code goes here to put text in this textbox
                    ctl.Text = "BBBB"
            End Select
        End If
    Next
End Sub

Когда вы запустите его, вы получите

ХТН