Попробуйте указать $date как фактическую дату/время:

let $date:= xs:dateTime($item/pubDate/text())

Если формат даты/времени согласован, вы можете реализовать свой собственный конвертер. Две части, которые доставят вам больше всего проблем, в примере из вашего комментария, это месяц и часовой пояс. Месяц должен быть числовым, и вам нужно будет преобразовать часовой пояс в эквивалентное смещение UTC.

Вот пример:

declare variable $months := ('jan','feb','mar','apr','may','jun','jul','aug','sep','oct','nov','dec');
declare variable $timezoneMap := 
    <map>
        <tz>
            <numeric>-05:00</numeric>
            <alpha>est</alpha>
        </tz>
    </map>;

declare function local:formatDate($origdate as xs:string) as xs:dateTime {
    let $dateTokens := tokenize($origdate,' ')  
    let $timezone := $timezoneMap/tz[lower-case($dateTokens[6])=alpha]/numeric/text()
    let $month := string(index-of($months,lower-case($dateTokens[3])))
    let $newDate := concat($dateTokens[4],'-',if (string-length($month)=1) then concat('0',$month) else $month,'-',$dateTokens[2],
                           'T',$dateTokens[5],$timezone)
    return
        xs:dateTime($newDate)
};

Затем вы можете использовать функцию следующим образом:

let $date:= local:formatDate($item/pubDate)

Кроме того, если вы используете XQuery 3.0, вы можете использовать карты. для часового пояса и месяца:

declare namespace map = "http://www.w3.org/2005/xpath-functions/map";
declare variable $months := map{"jan":="01","feb":="02","mar":="03","apr":="04","may":="05","jun":="06",
                                "jul":="07","aug":="08","sep":="09","oct":="10","nov":="11","dec":="12"};
declare variable $timezoneMap := map{"est":="-05:00"};

declare function local:formatDate($origdate as xs:string) as xs:dateTime {
    let $dateTokens := tokenize($origdate,' ')
    let $newDate := concat($dateTokens[4],'-',$months(lower-case($dateTokens[3])),'-',$dateTokens[2],
                           'T',$dateTokens[5],$timezoneMap(lower-case($dateTokens[6])))
    return
        xs:dateTime($newDate)
};

Создание парсера формата даты в XQuery, вероятно, не лучшая идея; вам придется иметь дело со всем этим преобразованием часовых поясов (и, что еще хуже, с переходом на летнее время...) самостоятельно.

Официальный способ: DateTime-Module

БД eXist имеет собственный модуль DateTime на основе java.text.SimpleDateFormat. Модуль должен быть скомпилирован и активирован перед его использованием и не включен в текущую стабильную версию eXists (но в версию для разработчиков 1.4.3 и предварительную версию 2).

Если вам удалось включить его (если вы этого не сделали, это, вероятно, еще один вопрос на Администраторе базы данных, родственном сайте SO), вы должны иметь возможность запускать этот код для анализа дат в указанном формате:

import module namespace datetime = "http://exist-db.org/xquery/datetime";
datetime:parse-dateTime('Mon, 10 Dec 2012 13:32:24 GMT', 'EEE, d MMM yyyy HH:mm:ss Z')

Грязный хак: взаимодействие с Java

Если вы используете более старую версию eXist или не можете использовать модуль по другим причинам, вы можете активировать привязки Java в conf.xml и вызвать эту функцию напрямую:

declare namespace sdtf="java:java.text.SimpleDateFormat";
declare namespace date="java:java.util.Date";

(: Parse given date format to java date :)    
let $parse := sdtf:new('EEE, d MMM yyyy HH:mm:ss Z')
(: Output as close to XQuery's xs:dateTime as possible :)
let $format := sdtf:new("yyyy-MM-dd'T'HH:mm:ss.SSSZ")
let $javadate := sdtf:parse($parse, 'Mon, 10 Dec 2012 13:32:24 GMT')
(: Use regex to insert missing ':' and finally cast to xs:dateTime :)
return xs:dateTime(fn:replace(sdtf:format($format, $javadate), '(.*)(\d{2})', '$1:$2'))

Опять же, не забудьте установить язык Java на английский, если он не установлен по умолчанию.

Думаю, это должно работать нормально, по крайней мере, в Saxon (который определил эту привязку java) и BaseX (на самом деле я проверял это здесь).

Вы можете использовать модуль Date Parser на основе XQuery Райана Гримма. Он создан для MarkLogic, но с небольшими изменениями должен работать и на других системах. См. https://github.com/marklogic/commons/blob/master/dates/date-parser.xqy.

Как указано в комментариях к модулю, поддерживаются следующие форматы даты:

1. 30 июн 2006 09:39:08 -05:00
2. 16 апреля 13:49:06 2003 +0200
3. 04 августа 11:44:58 по восточному поясному времени 2003 г.
4. 4 января 1998 г., 0:41 по восточному поясному времени
5. 25 октября 2004 г. 17:06:46 -0500
6. Пн, 23 сен 0102 23:14:26 +0900