GetKeyState в firemonkey

В VCL (Delphi 2010) я использовал эту функцию, чтобы проверить, нажата ли клавиша управления:

function IsControlKeyPressed: Boolean;
begin
  Result := GetKeyState(VK_CONTROL) < 0;
end;

GetKeyState — это функция в библиотеке Windows, которую я не хочу включать в свой проект.

Как я могу проверить, нажата ли клавиша управления или Shift в XE3 для приложения firemonkey?


keyboard delphi firemonkey delphi-xe3 firemonkey-fm2
person AvgustinTomsic    schedule 21.11.2012    source источник
comment
Взгляните на this post.   -  person TLama    schedule 21.11.2012
comment
@TLama Спасибо за ссылку. Это решение предназначено только для компьютеров Mac. Я искал независимое от платформы решение. Я решу это с помощью директив компилятора.   -  person AvgustinTomsic    schedule 21.11.2012

Ответы (4)


arrow_upward
4
arrow_downward

Если это поможет кому-то еще, это мой блок:

unit uUtils;

interface

uses
{$IFDEF MSWINDOWS}
  Winapi.Windows;
{$ELSE}
  Macapi.AppKit;
{$ENDIF}
function IsControlKeyPressed: Boolean;
function IsShiftKeyPressed: Boolean;

implementation

function IsControlKeyPressed: Boolean;
begin
{$IFDEF MSWINDOWS}
  Result := GetKeyState(VK_CONTROL) < 0;
{$ELSE}
  Result := NSControlKeyMask and TNSEvent.OCClass.modifierFlags = NSControlKeyMask;
{$ENDIF}
end;

function IsShiftKeyPressed: Boolean;
begin
{$IFDEF MSWINDOWS}
  Result := GetKeyState(VK_SHIFT) < 0;
{$ELSE}
  Result := NSShiftKeyMask and TNSEvent.OCClass.modifierFlags = NSShiftKeyMask;
{$ENDIF}
end;

end.
person AvgustinTomsic    schedule 22.11.2012

arrow_upward
2
arrow_downward

Не забудьте добавить следующее в модуль uUtils для правильной работы:

System.UITypes и Macapi.CoreGraphics.

uses
System.UITypes,
{$IFDEF MSWINDOWS}
  Winapi.Windows;
{$ELSE}
  Macapi.AppKit, Macapi.CoreGraphics;
{$ENDIF}
person JohanB    schedule 27.11.2014

arrow_upward
0
arrow_downward

Я расширил это на основе приведенной выше проверки кода, если какая-либо клавиша не работает, на основе vkKeyCode (и некоторых переводов для Mac)

function KeyIsDown(KeyInQuestion:Integer):Boolean;
begin
{$IFDEF MSWINDOWS}
   result:=GetAsyncKeyState(KeyInQuestion) AND $FF00 <> 0;
{$ENDIF MSWINDOWS}
{$IFDEF MACOS}
  {$INCLUDE WinVKeyToMacVKey.Inc}
  case KeyInQuestion of
  vkLButton: result:= Macapi.AppKit.TNSEvent.OCClass.pressedMouseButtons = 1;
  vkRButton: result:= Macapi.AppKit.TNSEvent.OCClass.pressedMouseButtons = (1 SHL 1);
  vkMButton: result:= Macapi.AppKit.TNSEvent.OCClass.pressedMouseButtons = (1 SHL 2);
 else
   result:=(CGEventSourceKeyState(0, KeyInQuestion) <> 0);
 end;
{$ENDIF MACOS}
//This is so it's not left/right-centric vkShift will return true
//if either vkShift or vkRShift is down
  if not result then
   case KeyInQuestion of
    vkShift:result:=KeyIsDown(vkRShift);
    vkControl:result:=KeyIsDown(vkRControl);
    vkMenu:result:=KeyIsDown(vkRMenu);
   end;
end;
person Ken Schafer    schedule 03.06.2013

arrow_upward
0
arrow_downward

вот текст файла WinVKeyToMacVKey.Inc

case KeyInQuestion of
   vkReturn: KeyInQuestion := $24;
   vkTab: KeyInQuestion := $30;
   vkSpace: KeyInQuestion := $31;
   vkBack: KeyInQuestion := $33;
   vkEscape: KeyInQuestion := $35;
   vkLWin: KeyInQuestion := $37;
   vkRWin: KeyInQuestion := $37;
   vkShift: KeyInQuestion := $38;
   vkMenu: KeyInQuestion := $3A;
   vkControl: KeyInQuestion := $3B;
   vkRShift: KeyInQuestion := $3C;
   vkRMenu: KeyInQuestion := $3D;
   vkRControl: KeyInQuestion := $3E;
   vkF17: KeyInQuestion := $40;
   vkVolumeUp: KeyInQuestion := $48;
   vkVolumeDown: KeyInQuestion := $49;
   vkF18: KeyInQuestion := $4F;
   vkF19: KeyInQuestion := $50;
   vkF20: KeyInQuestion := $5A;
   vkF5: KeyInQuestion := $60;
   vkF6: KeyInQuestion := $61;
   vkF7: KeyInQuestion := $62;
   vkF3: KeyInQuestion := $63;
   vkF8: KeyInQuestion := $64;
   vkF9: KeyInQuestion := $65;
   vkF11: KeyInQuestion := $67;
   vkF13: KeyInQuestion := $69;
   vkF16: KeyInQuestion := $6A;
   vkF14: KeyInQuestion := $6B;
   vkF10: KeyInQuestion := $6D;
   vkF12: KeyInQuestion := $6F;
   vkF15: KeyInQuestion := $71;
   vkHelp: KeyInQuestion := $72;
   vkHome: KeyInQuestion := $73;
   vkPrior: KeyInQuestion := $74;
   vkDelete: KeyInQuestion := $75;
   vkF4: KeyInQuestion := $76;
   vkEnd: KeyInQuestion := $77;
   vkF2: KeyInQuestion := $78;
   vkNext: KeyInQuestion := $79;
   vkF1: KeyInQuestion := $7A;
   vkLeft: KeyInQuestion := $7B;
   vkRight: KeyInQuestion := $7C;
   vkDown: KeyInQuestion := $7D;
   vkUp: KeyInQuestion := $7E;
end;
person Ken Schafer    schedule 03.06.2013