Почему экземпляр Functor с двумя кортежами применяет функцию только ко второму элементу?

Позвольте мне ответить на этот вопрос: какой результат вы ожидаете для:

main = print $ fmap (*2) ("funny",2)

Вы можете иметь что-то, что хотите (используя data Pair a = Pair a a или около того), но поскольку (,) может иметь разные типы в первом и втором аргументе, вам не повезло.

Пары, по сути, определяются следующим образом:

data (,) a b = (,) a b

Класс Functor выглядит так:

class Functor f where
  fmap :: (a -> b) -> f a -> f b

Так как типы аргументов и результатов функций должны иметь вид * (т.е. они представляют собой значения, а не функции типов, которые можно применять дальше или более экзотические вещи), мы должны иметь a :: *, b :: * и, что наиболее важно для наших целей, f :: * -> *. Поскольку (,) имеет тип * -> * -> *, его необходимо применить к типу типа *, чтобы получить тип, подходящий для Functor. Таким образом

instance Functor ((,) x) where
  -- fmap :: (a -> b) -> (x,a) -> (x,b)

Так что на самом деле нет никакого способа написать экземпляр Functor, делающий что-то еще.

Один полезный класс, который предлагает больше способов работы с парами, — это Bifunctor из Data.Bifunctor.

class Bifunctor f where
  bimap :: (a -> b) -> (c -> d) -> f a c -> f b d
  bimap f g = first f . second g

  first :: (a -> b) -> f a y -> f b y
  first f = bimap f id

  second :: (c -> d) -> f x c -> f x d
  second g = bimap id g

Это позволяет вам писать что-то вроде следующего (из Data.Bifunctor.Join):

  newtype Join p a =
    Join { runJoin :: p a a }

  instance Bifunctor p => Functor (Join p) where
    fmap f = Join . bimap f f . runJoin

Join (,) тогда по существу совпадает с Pair, где

data Pair a = Pair a a

Конечно, вы также можете просто использовать экземпляр Bifunctor для непосредственной работы с парами.

Экземпляр Functor на самом деле взят из Модуль GHC.Base, импортированный Control.Applicative.

Пытаясь написать экземпляр, который я хочу, я вижу, что он не будет работать, учитывая определение кортежей; для экземпляра требуется только один параметр типа, а для двух кортежей — два.

Действительный экземпляр Functor по крайней мере должен быть в кортежах, (a,a) которые имеют один и тот же тип для каждого элемента, но вы не можете сделать ничего скрытого, например, определить экземпляр на:

 type T2 a = (a,a)

потому что типы экземпляров не могут быть синонимами.

Приведенный выше ограниченный синоним из двух кортежей логически совпадает с типом:

data T2 a = T2 a a

который может иметь экземпляр Functor:

instance Functor T2 where
    fmap f (T2 x y) = T2 (f x) (f y)

Как заметил Габриэль в комментариях, это может быть полезно для ветвящихся структур или параллелизма.