Как преобразовать эту функцию для использования хвостового вызова

Как предложил @Ramon, вы должны использовать сопоставление с образцом для лучшей читабельности:

let rec listMerge xs ys =
    match xs, ys with
    | [], _ -> ys
    | _, [] -> xs
    | x::xs', y::ys' -> x::y::listMerge xs' ys'

Как видите, два cons-конструктора (::) являются последними операциями над listMerge, поэтому функция не является хвостовой рекурсией.

Вы можете использовать аккумулятор для получения результатов хвостовой рекурсией:

let listMerge xs ys =
    let rec loop xs ys acc =
        match xs, ys with
        | [], zs | zs, [] -> (List.rev zs)@acc
        | x::xs', y::ys' -> loop xs' ys' (y::x::acc)
    List.rev (loop xs ys [])

В приведенной выше функции первого вызова List.rev можно было бы избежать, если добавить еще несколько шаблонов для деконструкции двух списков, пока они оба не станут пустыми.

В F# существует подход с хвостовой рекурсией, использующий выражения последовательности, которые соответствуют строке стиль перехода продолжения:

let listMerge xs ys =
    let rec loop xs ys =
        seq {
            match xs, ys with
            | [], zs | zs, [] -> yield! zs
            | x::xs', y::ys' -> 
                yield x
                yield y
                yield! loop xs' ys'
        }
    loop xs ys |> Seq.toList

Мне нравится этот подход, поскольку он удобен и близок к вашей исходной формулировке.

Вы можете накапливать сконструированный результат при последующих вызовах listMerge и, наконец, возвращать накопленный результат. Мои навыки F# довольно заржавели, но вот простая функция Lisp.

(defun list-merge (xs ys &optional acc)
  (cond ((< 0 (length xs)) (list-merge (rest xs) ys (cons (first xs) acc)))
        ((< 0 (length ys)) (list-merge xs (rest ys) (cons (first ys) acc)))
        (t acc)))

(list-merge '(1 2 3) '(3 4 5)) ;=> (5 4 3 3 2 1)
(list-merge '() '(1 2))        ;=> (2 1)
(list-merge '() '())           ;=> nil

Простая версия с использованием аккумулятора:

let rec listMerge (l1 : 'a list) (l2 : 'a list) acc =
    if l1.IsEmpty then      (List.rev l2)@acc 
    elif l2.IsEmpty then    (List.rev l1)@acc
    else                    listMerge l1.Tail l2.Tail (l1.Head :: l2.Head :: acc)

Я проверил это с двумя миллионами списков элементов, и не было переполнения стека, поэтому я достаточно уверен, что это хвостовая рекурсия.

Я думаю, вам придется повторно использовать исходный код F# из F# PowerPack.
Собственно, то, что вам нужно равно List.fold2, за исключением того, что функция не должна генерировать исключение SR.listsHadDifferentLengths в случае, если размеры списка различаются, а вместо этого должна обрабатывать оставшуюся часть более длинного списка, например:

let l1 = ["A1"; "A2"; "A3"; "A4"; "A5"; "A6"; "A7"]
let l2 = ["B1"; "B2"; "B3"; "B4"]

let expectedResult = ["A1"; "B1"; "A2"; "B2"; "A3"; "B3"; "A4"; "B4"; "A5"; "A6"; "A7"]

Вот как мы это делаем:

[<CompiledName("Fold2Tail")>]
let fold2Tail<'T1,'T2,'State> f g1 g2 (acc:'State) (list1:list<'T1>) (list2:list<'T2>) = 
    let f  = OptimizedClosures.FSharpFunc<_,_,_,_>.Adapt(f)
    let g1 = OptimizedClosures.FSharpFunc<_,_,_>.Adapt(g1)
    let g2 = OptimizedClosures.FSharpFunc<_,_,_>.Adapt(g2)
    let rec loop acc list1 list2 =
        match list1, list2 with 
        | [], [] -> acc
        | _,  []  -> g1.Invoke(acc, list1)
        | [], _   -> g2.Invoke(acc, list2)
        | (h1::t1),(h2::t2) -> loop (f.Invoke(acc,h1,h2)) t1 t2
    loop acc list1 list2

g1 и g2 являются предикатами типа 'State -> 'T1 list -> 'State и 'State -> 'T2 list -> 'State соответственно. Они говорят, как обрабатывать остатки обоих списков. Обратите внимание, что их два, так как в общем случае 'T1 и 'T2 — это разные типы. Да, это несколько накладно, но вы легко можете уменьшить его под свои нужды, пожертвовав универсальностью.

Применение:

let ret =
    fold2Tail
        (fun s x y  -> [ yield! s; yield x; yield y ] ) // f
        List.append // g1
        List.append // g2
        []          // 'State
        l1 l2

Вы должны использовать сопоставление с образцом:

let rec merge xs ys =
  match xs, ys with
  | [], xs | xs, [] -> xs
  | x::xs, y::ys -> x::y::merge xs ys

Чтобы получить хвостовые вызовы, вы можете использовать аккумулятор:

let merge xs ys =
  let rec loop xys xs ys =
    match xs, ys with
    | [], xs | xs, [] -> List.fold (fun xs x -> x::xs) xs xys
    | x::xs, y::ys -> loop (y::x::xys) xs ys
  loop [] xs ys

или стиль прохождения продолжения:

let merge xs ys =
  let rec loop xs ys k =
    match xs, ys with
    | [], xs | xs, [] -> k xs
    | x::xs, y::ys -> loop xs ys (fun xys -> k(x::y::xys))
  loop xs ys id