Perl — переместить указатель в начало строки

Прежде всего, вы должны использовать лексические дескрипторы файлов, трехпараметрическую форму open и всегда проверять статус, чтобы убедиться, что open выполнено успешно (как вы делаете с файлом сопоставления, но не с входным файлом).

Предлагаемое вами решение перематывать к началу строки перед использованием print не будет работать, потому что вы не можете обновить часть файла, если ваши замещающие данные не точно того же размера, что и заменяемые данные. Обычно в вашей ситуации это не так.

Для этого есть ряд решений, первое и самое простое — инвертировать циклы и поместить цикл чтения для файла сопоставления внутри цикла чтения для входного файла. Ваш код будет выглядеть так:

use strict;
use warnings;

my ($mapping, $input) = @ARGV;

open my $infh, '<', $input or die "Unable to open '$input': $!";

while (my $line = <$input>) {

  open my $mapfh, '<', $mapping or die "Unable to open '$mapping': $!";

  while (<$mapfh>) {
    chomp;
    my ($key, $value) = split /=/;
    $line =~ s/\Q$key/$value/g;
  }
  print $line;
}

но ваш вывод отправляется в STDOUT, и вам нужно будет сохранить вывод в файл и соответствующим образом переименовать.

Альтернативой здесь является использование параметра командной строки -I, который заставляет файл автоматически переименовываться и при необходимости сохранять резервную копию. Использование голого -I изменит файл на месте, удалив старый файл и переименовав новый вывод, а присвоение параметру значения, подобного -I.bak, переименует старый файл, добавив .bak вместо его удаления. Параметр -I применяется только к файлам, считанным из ARGV с использованием пустого оператора <>, и установка значения встроенной переменной $^I (или пустой строки '') имеет тот же эффект. Код выглядит следующим образом:

use strict;
use warnings;

my $mapping = shift @ARGV;
$^I = '.bak';

while (my $line = <>) {

  open my $mapfh, '<', $mapping or die "Unable to open '$mapping': $!";

  while (<$mapfh>) {
    chomp;
    my ($key, $value) = split /=/;
    $line =~ s/\Q$key/$value/g;
  }
  print $line;
}

Третий и более удобный вариант — использовать Tie::File, который сопоставляет массив Perl с файлом. содержимое и отражает все изменения массива обратно в исходный файл. Вот пример:

use strict;
use warnings;

use Tie::File;

my ($mapping, $input) = @ARGV;
tie my @input, 'Tie::File', $input or die "Unable to open '$input': $!";

for my $line (@input) {

  open my $mapfh, '<', $mapping or die "Unable to open '$mapping': $!";

  while (<$mapfh>) {
    chomp;
    my ($key, $value) = split /=/;
    $line =~ s/\Q$key/$value/g;
  }
}

Наконец, очень неэффективно постоянно открывать и читать файл сопоставления для каждой строки ввода, и лучше всего построить регулярное выражение из его содержимого и использовать его во всей программе. Эта версия сначала строит хэш %mapping из файла сопоставления, а затем создает регулярное выражение, применяя quotemeta к каждому ключу хэша, чтобы избежать любых метасимволов регулярного выражения, а затем соединяя их с помощью оператора чередования регулярных выражений |. Ключи сортируются по убыванию длины, так что самые длинные совпадения находятся и заменяются в приоритете над более короткими.

use strict;
use warnings;

use Tie::File;

my ($mapping, $input) = @ARGV;

open my $mapfh, '<', $mapping or die "Unable to open '$mapping': $!";
my %mapping = map { chomp; /\S/ ? split /=/ : () } <$mapfh>;
my $regex = join '|', map quotemeta, sort { length $b <=> length $b } keys %mapping;

tie my @input, 'Tie::File', $input or die "Unable to open '$input': $!";

for my $line (@input) {
  $line =~ s/($regex)/$mapping{$1}/g;
}

Если бы я мог переместить указатель файла в начало строки, я мог бы перезаписать его:

print INPUT $_,"\n"

Ваша предпосылка неверна: если принять последовательность байтов 00 01 02 и правило 01 = A1 A2, результирующая последовательность байтов будет 00 A1 A2, а не 00 A1 A2 02. Способы обойти это включают:

• Используйте модуль Tie::File.
• Запишите в другой файл и переименуйте второй файл в исходный после завершения прохода. Это, вероятно, наиболее эффективно и масштабируемо.

seeking не является хорошей идеей: вы будете ограничены подстановками фиксированной длины, а seek и tell работают с байтами, а не с символами. Если вам действительно нужно использовать редактирование на месте, вы можете использовать этот цикл:

my $beginning_of_line = tell $fh;
while (<$fh>) {
  # do processing
  seek $fh, $beginning_of_line, 0;
  # do update
} continue {$beginning_of_line = tell $fh}

Кроме того, вы делаете несколько проходов по входному файлу. Предполагая последовательность токенов a b c и правила b = d e и d = f, вы получите последовательности a f e c или a d e c в зависимости от порядка правил! Возможно, это не то, что вам нужно.
Также обратите внимание на неоднозначность правил a = c и a b = d для входных данных a b. Получается ли это c b или d?