foreach внутри токенизации

Это фрагмент из xml:

<sample>
        <test>
            <Cell1>John</Cell1>
            <Cell2>A</Cell2>
            <Cell4>xy</Cell4>
        </test>
        <test>
            <Cell1>Jack</Cell1>
            <Cell2>B</Cell2>
            <Cell3>Red</Cell3>
            <Cell6>10</Cell6>
        </test>
        <test>
            <Cell1>John,Jade</Cell1>
            <Cell2>A,Y</Cell2>
            <Cell4>1</Cell4>
        </test>
        <test>
            <Cell1>John,Jade</Cell1>
            <Cell2>A B,X</Cell2>
            <Cell3>Blue</Cell3>
        </test>
    </sample>

Условия:

Если Cell2 содержит запятую, разделите значения и проверьте, содержит ли предыдущий Cell2 одно и то же значение, и аналогичным образом, если Cell2 содержит пробел, разделите значения и проверьте, содержит ли предыдущий Cell2 одно и то же значение -> Если да, игнорируйте его.

Вот как я хочу получить результат:

<Cell2>A</Cell2>
<Cell2>B</Cell2>
<Cell2>Y</Cell2>
<Cell2>X</Cell2>

Это xslt, который я написал: (пожалуйста, загляните в комментарий)

<xsl:template match="sample">
        <xsl:for-each select="test">
                <xsl:choose>
                    <xsl:when test="contains(Cell2,',')">
                        <xsl:variable name="token1Cell2" select="tokenize(Cell2,',')"/>
                        <xsl:for-each select="$token1Cell2">
                            <xsl:choose>
                                <xsl:when test="contains(.,' ')">
                                    <xsl:variable name="token2Cell2" select="tokenize(.,' ')"/>
                                    <xsl:for-each select="$token2Cell2">
              <!-- I tried to check if the preceding sibling element test/Cell2 contains the text that is not equal to the current text. But I know what I am doing is wrong as I am inside for-each tokenize. How to get the preceding-sibling? -->
                                      <xsl:if test="preceding-sibling::test/
Cell2/text() != '.'">
                                        <Cell2>
                                            <xsl:value-of select="."/>
                                        </Cell2>
                                        </xsl:if>
                                    </xsl:for-each>
                                </xsl:when>
                                <xsl:otherwise>
                                <xsl:if test="preceding-sibling::test/Cell2/text() != '.'">
                                    <Cell2>
                                        <xsl:value-of select="."/>
                                    </Cell2>
                                </xsl:if>
                                </xsl:otherwise>
                            </xsl:choose>
                        </xsl:for-each>
                    </xsl:when>
                    <xsl:otherwise>
                        <Cell2>
                            <xsl:value-of select="Cell2"/>
                        </Cell2>
                    </xsl:otherwise>
                </xsl:choose>
        </xsl:for-each>
    </xsl:template>

Как я могу добиться результата? Любые идеи??


xslt xpath-2.0 xslt-2.0
person Shil    schedule 27.09.2012    source источник

Ответы (3)


arrow_upward
6
arrow_downward

Простое преобразование:

<xsl:stylesheet version="2.0"   xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/">
     <xsl:for-each select="distinct-values(/*/test/Cell2/tokenize(.,'[ ,]'))">
      <Cell2><xsl:value-of select="."/></Cell2>
     </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

при применении к предоставленному XML-документу:

<sample>
    <test>
        <Cell1>John</Cell1>
        <Cell2>A</Cell2>
        <Cell4>xy</Cell4>
    </test>
    <test>
        <Cell1>Jack</Cell1>
        <Cell2>B</Cell2>
        <Cell3>Red</Cell3>
        <Cell6>10</Cell6>
    </test>
    <test>
        <Cell1>John,Jade</Cell1>
        <Cell2>A,Y</Cell2>
        <Cell4>1</Cell4>
    </test>
    <test>
        <Cell1>John,Jade</Cell1>
        <Cell2>A B,X</Cell2>
        <Cell3>Blue</Cell3>
    </test>
</sample>

выдает желаемый правильный результат:

<Cell2>A</Cell2>
<Cell2>B</Cell2>
<Cell2>Y</Cell2>
<Cell2>X</Cell2>

Пояснение:

Выражение XPath в атрибуте select элемента xsl:for-each является ключом к пониманию:

distinct-values(/*/test/Cell2/tokenize(.,'[ ,]'))

Это создает различные значения последовательности всех токенизированных (строковых значений) /*/test/Cell2

person Dimitre Novatchev    schedule 27.09.2012

arrow_upward
4
arrow_downward

Для начала, если вы токенизируете запятую или пробел, вы можете объединить токенизацию в одно выражение.

<xsl:for-each select="tokenize(., ',|\s')">

Что вы можете сделать, так это сначала сопоставить все элементы Cell2 с вашим шаблоном, размечающим содержимое, но поместить результаты в переменную.

  <xsl:variable name="cells">
     <xsl:apply-templates select="test/Cell2"/>
  </xsl:variable>

Затем вы можете просто использовать xsl:for-each-group для их перебора.

  <xsl:for-each-group select="$cells/Cell2" group-by="text()">
     <xsl:copy-of select="."/>
  </xsl:for-each-group>

Вот полный XSLT

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes"/>
   <xsl:template match="sample">
      <xsl:variable name="cells">
         <xsl:apply-templates select="test/Cell2"/>
      </xsl:variable>
      <xsl:for-each-group select="$cells/Cell2" group-by="text()">
         <xsl:copy-of select="."/>
      </xsl:for-each-group>
   </xsl:template>

   <xsl:template match="Cell2">
      <xsl:for-each select="tokenize(., ',|\s')">
         <Cell2>
            <xsl:value-of select="."/>
         </Cell2>
      </xsl:for-each>
   </xsl:template>
</xsl:stylesheet>

При применении к вашему образцу XML выводится следующее

<Cell2>A</Cell2>
<Cell2>B</Cell2>
<Cell2>Y</Cell2>
<Cell2>X</Cell2>
person Tim C    schedule 27.09.2012
comment
TimC, атрибут версии должен быть 2.0. И @Shil, есть гораздо более простое решение. - person Dimitre Novatchev; 27.09.2012
comment
Ах да, это я исправил. И да, ваше решение намного проще! - person Tim C; 27.09.2012

arrow_upward
2
arrow_downward

Когда у вас есть глубоко вложенные инструкции xsl:for-each, элемент контекста меняется на каждом уровне, поэтому вам часто нужно привязать переменную к элементу контекста на каждом уровне, чтобы вы могли вернуться к нему. Однако глубоко вложенные инструкции xsl:for-each иногда указывают на то, что код следует разбить на более мелкие шаблоны или функции.

person Michael Kay    schedule 27.09.2012