Как отправить событие с добавленными данными — AS3

Если вы хотите передать объект через событие, вы должны создать собственное событие. Код должен быть примерно таким.

public class MyEvent extends Event
{
    public static const GOT_RESULT:String = "gotResult";

    // this is the object you want to pass through your event.
    public var result:Object;

    public function MyEvent(type:String, result:Object, bubbles:Boolean=false, cancelable:Boolean=false)
    {
        super(type, bubbles, cancelable);
        this.result = result;
    }

    // always create a clone() method for events in case you want to redispatch them.
    public override function clone():Event
    {
        return new MyEvent(type, result, bubbles, cancelable);
    }
}

Затем вы можете использовать приведенный выше код следующим образом:

dispatchEvent(new MyEvent(MyEvent.GOT_RESULT, result));

И вы слушаете это событие там, где это необходимо.

addEventListener(MyEvent.GOT_RESULT, myEventHandler);
// more code to follow here...
protected function myEventHandler(event:MyEvent):void
{
    var myResult:Object = event.result; // this is how you use the event's property.
}

Этот пост немного устарел, но если он может кому-то помочь, вы можете использовать класс DataEvent следующим образом:

dispatchEvent(new DataEvent(YOUR_EVENT_ID, true, false, data));

Документация

При правильном дизайне вам не нужно передавать объект в событие.
Вместо этого вы должны создать публичную переменную в классе диспетчеризации.

public var myObject:Object;

// before you dispatch the event assign the object to your class var
myObject = ....// whatever it is your want to pass
// When you dispatch an event you can do it with already created events or like Tomislav wrote and create a custom class.

// in the call back just use currentTarget
public function myCallBackFunction(event:Event):void{

  // typecast the event target object
  var myClass:myClassThatDispatchedtheEvent = event.currentTarget as myClassThatDispatchedtheEvent 
  trace( myClass.myObject )// the object or var you want from the dispatching class.