Как указать каталог сборки в Qt Creator для теневой сборки без использования абсолютного пути?

По крайней мере, в Qt Creator 3.6.1 это исправлено — относительные пути работают нормально. Разрешенный полный путь отображается во всплывающей подсказке. Я не знаю, когда за последние несколько лет это было исправлено.

Не совсем теневые сборки, как их определяет qt-creator, но я использую следующее, чтобы получить аккуратную структуру сборки.

Выдержка из профайла для библиотеки, которую я собираю для нескольких целей, а также в тестовых режимах.

TARGET = ../lib/common
message("libcommon:")

contains(CONFIG,test){
  message("Building Test")
  DESTDIR = test
  TARGET = $$TARGET-test
}else{
  message("Building Program")
  DESTDIR = program
  TARGET = $$TARGET
}

contains(MEEGO_EDITION,harmattan){
  message("Maemo Harmattan")
  DESTDIR = $$DESTDIR-maemo6
  TARGET = $$TARGET-maemo6
  DEFINES += MAEMO MAEMO6
}
unix:!maemo5:!contains(MEEGO_EDITION,harmattan){#desktop
  message("Desktop")
  DESTDIR = $$DESTDIR-desktop
  TARGET = $$TARGET-desktop
}

contains(CONFIG,test){
  TEMPLATE = app
  SOURCES += $$files(src_test/main.cpp)
  HEADERS += $$files(src_test/*.h)
  INCLUDEPATH += src_test
}else{
  TEMPLATE = lib
  CONFIG += staticlib
}

CONFIG(debug, debug|release) {
  message("Debug")
  DESTDIR = $$DESTDIR-debug
  CONFIG += debug
  DEFINES += DEBUG
  TARGET = $$TARGET-debug
}else{
  message("Release")  
  //DEFINES += QT_NO_DEBUG_OUTPUT
  DESTDIR = $$DESTDIR-release
  TARGET = $$TARGET-release
}
MOC_DIR = build/$${DESTDIR}/moc
OBJECTS_DIR = build/$${DESTDIR}/obj
UI_DIR = build/$${DESTDIR}/ui

Таким образом, вы получаете все свои файлы объектов, moc, gui в отдельных каталогах (например, libcommon/build/program-desktop-debug/moc) и свои двоичные файлы в одном и том же с разными именами. Чтобы запустить ту или иную сборку, вы просто устанавливаете CONFIG+= в цели сборки. И самое лучшее в этом, эта структура зависит только от файла pro, и вы можете поместить его части в общий.pri и использовать его для всех своих проектов. Больше нет необходимости в настройке теневой сборки. Кстати, файл pro находится в libcommon/libcommon.pro, как и должно быть.

Я использую этот код в файле *.pro, он работает нормально.

CONFIG(debug, debug|release){
    DESTDIR=$$shadowed($$ROOT_PWD)/debug
}else{
    DESTDIR=$$shadowed($$ROOT_PWD)/release
}

Есть несколько вещей, которые можно использовать, чтобы сделать это управляемым:

Переменная $$_PRO_FILE_PWD_ (версия >=4.5) содержит каталог текущего прочитанного файла pro.

Используйте файл .qmake.cache в корневом каталоге проекта и определите переменную для каталога:

PROJECT_DIR = $$PWD

Затем используйте это для навигации, начиная с корня.