VBScript и loadXML: недопустимы на верхнем уровне документа. Как это исправить?

xmlDoc.loadXML() может загрузить строку XML. Он не может получить URL.

Используйте объект XMLHTTPRequest, если вам нужно сделать HTTP-запрос.

Function LoadXml(xmlurl)
  Dim xmlhttp

  Set xmlhttp = CreateObject("MSXML2.XMLHTTP")
  xmlhttp.Open "GET", xmlurl, false

  ' switch to manual error handling
  On Error Resume Next

  xmlhttp.Send
  If err.number <> 0 Then 
    WScript.Echo xmlhttp.parseError.Reason
    Err.Clear
  End If 

  ' switch back to automatic error handling 
  On Error Goto 0

  Set LoadXml = xmlhttp.ResponseXml
End Function

Используйте как

Set doc = LoadXml("http://your.url/here")

Три дополнительных замечания:

(1) Поскольку .parseError.reason имеет тенденцию быть загадочным, стоит включить его свойство .srcTxt (и параметр для .loadXml):

  Dim xmlurl : xmlurl = "song.xml"
  Dim xmlDoc : Set xmlDoc = CreateObject("Microsoft.XMLDOM")
  xmlDoc.async = False
  xmlDoc.loadXML xmlurl
  If 0 <> xmlDoc.parseError.errorcode Then
     WScript.Echo xmlDoc.parseError.reason, "Src:", xmlDoc.parseError.srcText
  Else
     WScript.Echo "surprise, surprise"
  End if

выход:

Invalid at the top level of the document.
 Src:  song.xml

Конечно, написать функцию/подпрограмму, которая учитывает все свойства .parseError и использовать ее всегда, было бы еще лучше.

(2) Чтобы загрузить файл или URL-адрес, используйте .load:

  Dim xmlDoc : Set xmlDoc = CreateObject("Microsoft.XMLDOM")
  Dim xmlurl
  For Each xmlurl In Array("song.xml", "http://gent/~eh/song.xml", "zilch")
    xmlDoc.async = False
    if xmlDoc.load(xmlurl) Then
       With xmlDoc.documentElement.firstChild
          WScript.Echo    xmlurl _
                       , .tagName _
                       , .firstChild.tagName _
                       , .firstChild.text
       End With
    Else
       WScript.Echo xmlurl, xmlDoc.parseError.reason, "Src:", xmlDoc.parseError.srcText
    End if
  Next

выход:

song.xml nowplaying-info property CKOI-ÄÖÜ
http://gent/~eh/song.xml nowplaying-info property CKOI-ÄÖÜ
zilch The system cannot locate the object specified.
 Src:

(3) Использование DOM позволяет избежать всех проблем с кодировкой (поэтому я поместил несколько умлаутов на немецком языке в «ваш» файл, который даже попал в вывод DOS-Box) и делает RegExps (даже Perl) вторым лучшим выбором.