Обрезка массива (заполненного через DBI)

Я пытаюсь прочитать данные из базы данных SQL Server, используя Perl и модуль DBI. Я намерен прочитать данные и распечатать их в текстовый файл (через запятую). Когда я это делаю, я получаю такой результат:

var1,var2,var3
40406,20 ,783
50230,78 ,680
50230,78 ,680
50230,78 ,680
50230,78 ,680

Таким образом, между данными второй переменной и запятой есть пробел. Я попытался обрезать это, используя приведенный ниже код, но это не сработало. Как мне изменить свой код, чтобы избавиться от этих пробелов?

Мой код здесь:

#!/bin/perl
use warnings;
use strict;
use DBI;

sub trim;

my $dbs = "dbi:ODBC:DRIVER={SQL Server};SERVER={xxxx}";
my ($username, $password) = ('un', 'pwd');

my $dbh = DBI->connect($dbs, $username, $password)
               or die "Can't connect to $dbs: $DBI::errstr";

my $sth = $dbh->prepare("select var1, var2, var3 from db.dbo.table")
                or die "Can't prepare statement: $DBI::errstr";

$sth->execute();

my $outfile = 'temp.txt';
open OUTFILE, '>', $outfile or die "Unable to open $outfile: $!";

print OUTFILE join(",", @{$sth->{NAME}}), "\n";

while (my @re = $sth->fetchrow_array) {
   print OUTFILE join(",", trim(@re)), "\n";
}

close OUTFILE;

$sth->finish();
$dbh->disconnect();

############## subroutines ##################
sub trim($) {
    my $string = shift;
    $string =~ s/^\s+//;
    $string =~ s/\s+$//;
    return $string;
}

arrays sql-server dbi perl
person rjuuser    schedule 08.07.2009    source источник
comment
Вы новичок, поэтому я расскажу вам стандартный этикет SO: 1.- Проголосуйте и примите ответы, особенно если они то, что вы хотели (против плохих ответов) 2.- Измените свой вопрос вместо добавления ответов, это не Форум. Рад, что это сработало!   -  person Vinko Vrsalovic    schedule 08.07.2009
comment
Вторя Винко, я собираюсь предложить вам принять его ответ и удалить неответы, которые вы разместили в качестве ответов.   -  person Sinan Ünür    schedule 09.07.2009

Ответы (3)


arrow_upward
5
arrow_downward

Ваша функция trim() не изменяет список на месте (и не обрабатывает список).

Таким образом, в реальном стиле TIMTOWTDI вы должны либо изменить функцию, чтобы она возвращала новый массив:

sub trimArray {
    my @arr = @_;
    my @rv;
    for my $val (@arr) {
        $val =~ s/^\s+//;
        $val =~ s/\s+$//;
        push @rv, $val;
    }
    return @rv;
}

#and then

print OUTFILE join(",", trimArray(@re)), "\n";

или передайте ссылку на свою функцию, а затем измените массив на месте

sub trimInPlace {
    my $arrRef = shift;
    for my $val (@$arrRef) {
        $val =~ s/^\s+//;
        $val =~ s/\s+$//;
    }
}

#and then

trimInPlace(\@re); #Note the \
print OUTFILE join(",", @re), "\n";

или используйте карту

#!/bin/perl
use warnings;
use strict;
use DBI;

#... the same

while (my @re = $sth->fetchrow_array) {
   print OUTFILE join(",", map { trim($_); } @re), "\n"; #Applies
                                                         #trim() to each element
}

#...

############## subroutines ##################
sub trim { #Don't use prototypes
    my $string = shift;
    $string =~ s/^\s+//;
    $string =~ s/\s+$//;
    return $string;
}

или попробуйте использовать chomp, изменив $/, что удалит только конечный пробел, и ничего более.

#!/bin/perl
use warnings;
use strict;
use DBI;

#... the same

my $old_sep = $/;
$/ = " ";
while (my @re = $sth->fetchrow_array) {
   chomp(@re); #Modifies in place, returning number of changes
   print OUTFILE join(",", @re), "\n";
}
$/ = $old_sep;
person Vinko Vrsalovic    schedule 08.07.2009
comment
trimInPlace почему-то не работал (не успел проверить почему). Массив внутри функции обрезается, но снаружи это не затрагивается. trimArray работает хорошо. - person Asaf Mesika; 24.05.2011
comment
trimInPlace работает с локальной копией @arr, должно работать с @$arrRef : … my $arrRef = shift; for my $val (@$arrRef) { $val =~ s/\s+$//; } - person tstrit; 19.11.2012

arrow_upward
1
arrow_downward

Вы также можете проверить, поддерживает ли DBD::ODBC атрибут ChopBlanks:

my $dbh = DBI->connect($dbs, $username, $password, { ChopBlanks => 1 } )

атрибут ChopBlanks обрезает завершающие пробелы любых полей CHAR (то есть, если ваш драйвер поддерживает это... Я не уверен, поддерживает ли DBD::ODBC).

person derby    schedule 09.07.2009
comment
DBD::ODBC поддерживает ChopBlanks, если столбец является символом. Если это не работает, пожалуйста, пришлите мне пример, и я посмотрю на него. - person bohica; 20.11.2012

arrow_upward
0
arrow_downward

Почему это поле имеет завершающий пробел? Обычно это указывает на какую-то проблему с моделью базы данных. Помимо вашей функции trim(), вы можете выяснить, почему данные грязные.

person brian d foy    schedule 10.07.2009
comment
Столбцы char(N) в MS SQL Server возвращаются как N символов, даже если вы вставили только N-M символов. Если вы не хотите, чтобы вы использовали столбцы varchar. - person bohica; 20.11.2012