Как сделать TWebBrowser Zoom при использовании Ctrl + колесико мыши, как это делает Internet Explorer?

Джейсонпенни,

100 — это значение по умолчанию, если вы хотите изменить масштаб, вы должны увеличить или уменьшить это значение от 10 до 1000.

Я написал тест, и вот код:

type
  TFormWebBrowserZoom = class(TForm)
    WebBrowser1: TWebBrowser;
    procedure FormMouseWheelDown(Sender: TObject; Shift: TShiftState; MousePos: TPoint; var Handled: Boolean);
    procedure FormMouseWheelUp(Sender: TObject; Shift: TShiftState; MousePos: TPoint; var Handled: Boolean);
    procedure FormShow(Sender: TObject);
  private
    FZoom: Integer;
    FLastZoom: Integer; 

    procedure ApplyZoom(ZoomValue: Integer);
    procedure DecZoom;
    procedure IncZoom;
  end;

implementation

const
  OLECMDID_OPTICAL_ZOOM = $0000003F;
  MinZoom = 10;
  MaxZoom = 1000;
  ZoomFactor = 20;
  DefaultZoom = 100;

procedure TFormWebBrowserZoom.FormShow(Sender: TObject);
begin
  WebBrowser1.Navigate('http://www.cesarromero.com.br');
  FZoom := DefaultZoom;
  FLastZoom := DefaultZoom;
end;

procedure TFormWebBrowserZoom.ApplyZoom(ZoomValue: Integer);
var
  pvaIn, pvaOut: OleVariant;
begin
  if ZoomValue = FLastZoom then
    Exit;
  FLastZoom := ZoomValue;
  pvaIn := ZoomValue;
  pvaOut := Null;
  WebBrowser1.ControlInterface.ExecWB(OLECMDID_OPTICAL_ZOOM, OLECMDEXECOPT_DONTPROMPTUSER, pvaIn, pvaOut);
end;

procedure TFormWebBrowserZoom.DecZoom;
begin
  System.Dec(FZoom, ZoomFactor);
  if FZoom < MinZoom then
    FZoom := MinZoom;
  ApplyZoom(FZoom);
end;

procedure TFormWebBrowserZoom.IncZoom;
begin
  System.Inc(FZoom, ZoomFactor);
  if FZoom > MaxZoom then
    FZoom := MaxZoom;
  ApplyZoom(FZoom);
end;

procedure TFormWebBrowserZoom.FormMouseWheelDown(Sender: TObject; Shift: TShiftState; MousePos: TPoint; var Handled: Boolean);
begin
  DecZoom;
end;

procedure TFormWebBrowserZoom.FormMouseWheelUp(Sender: TObject; Shift: TShiftState; MousePos: TPoint; var Handled: Boolean);
begin
  IncZoom;
end;

С http://msdn.microsoft.com/en-us/library/cc849094%28v=vs.85%29.aspx#OptInHighDPI:

Увеличение размера Интернета: масштабирование DPI и Интернет Проводник 8

Включение режима высокого разрешения для элементов управления веб-браузера (WebOC)

Чтобы сохранить совместимость с ранее разработанными WebOC, по умолчанию Internet Explorer 8 не отображает веб-контент WebOC с использованием поведения Internet Explorer 8 High DPI, а использует поведение Internet Explorer 7, которое масштабирует шрифты, указанные в абсолютных значениях. например точки. Чтобы воспользоваться преимуществами поведения Internet Explorer 8 High DPI в своих программах, необходимо использовать DOCHOSTUIFLAG с именем DOCHOSTUIFLAG_DPI_AWARE. Этот флаг используется с помощью метода GetHostInfo, который содержит DOCHOSTUIINFO. структура как один из его параметров. В свою очередь DOCHOSTUIINFO имеет оператор DWORD с именем dwFlags в качестве одного из своих членов, который может состоять из одного или нескольких значений DOCHOSTUIFLAG. Вы должны включить DOCHOSTUIFLAG_DPI_AWARE в dwFlags, чтобы воспользоваться преимуществом поведения Internet Explorer 8 с высоким разрешением в вашем WebOC.

Быстрый и простой способ смоделировать, как будет выглядеть HTML-контент ваших WebOC после выбора режима High-DPI, — открыть эквивалентный HTML-контент (составленный в HTML-файле) в Internet Explorer 8 и просто проверить рендеринг с эквивалентными настройками масштабирования (от 120 DPI до 125% увеличения, от 144 DPI до 150% увеличения). Мы рекомендуем вам протестировать WebOC в реальных сценариях с высоким разрешением, чтобы быть полностью уверенным, что содержимое HTML отображается так, как вы надеялись.